技术分析：布林带

布林带的关键点包括：中线、通道的宽度、通道的上下沿。

主图

主图可以说是最重要的部分。它最醒目，也最常用。

下面的公式在主图中显示布林带的中线，其实也就是20日均线。另加了一条10日均线。
布林带的上下沿并一画出。一来是因为上下沿会占据较大绘图空间；二来量化了的布林带宽和布林极限应该更具参考意义。

{N=20}

P1 := (H+L+C)/3;
P2 := (H+L+O+C)/4;
P3 := C;
P  := P1;

{MA5:MA(P,5);}
MA10:MA(P,10);
{MA60:MA(P,60);}

MID:=MA(P,N);
VART1:=POW((C-MID),2);
VART2:=MA(VART1,N);
VART3:=SQRT(VART2);
UPPER:=MID+2*VART3;
LOWER:=MID-2*VART3;
BOLL: REF(MID,1),COLORFFFFFF;
上升: IF(BOLL > REF(BOLL,1),BOLL,DRAWNULL),COLORRED,LINETHICK1;
下降: IF(BOLL < REF(BOLL,1),BOLL,DRAWNULL),COLORGREEN,LINETHICK1;
{UB:REF(UPPER,1),COLOR00FFFF;}
{LB:REF(LOWER,1),COLORFF00FF;}

{布林极限}
{%B := (C-LOWER)/(UPPER-LOWER); }
{布林带宽}
{BWIDTH:= (UPPER-LOWER)/MID;}

{平均真实波幅}
ATR10 := ATR(10);
  SELL : DRAWICON(C < REF(C,1)-REF(ATR10,1)*1.3,L*0.96,2);
{ BUY : DRAWICON(C > REF(C,1)+REF(ATR10,1)*1.3,H*1.04,1); }


{
移动速度 := REF(C,1)-REF(C,10);
波动幅度 := SUM(ABS(C-REF(C,1)),10);
效率比率 := 移动速度/波动幅度;
平滑常数 := 效率比率*0.60215 + 0.06452;
AMA10 : DMA(C, 平滑常数*平滑常数);
};

副图：布林极限

布林极限可以看作是对股价相对于布林通道的位置的量化。
1.0 对应于上轨；0.5 对应于中轨；0.1对应于下轨。

{额外 Y 轴分界：1.0，0.5，0.1}
{N=20}

P1:= (H+L+C)/3;
P2:= (H+L+O+C)/4;
P3 := C;
P  := P1;
MID:=MA(P,N);
VART3:=STD(P,N);
UPPER:=MID+2*VART3;
LOWER:=MID-2*VART3;

%M5 : (MA(P,5)-LOWER)/(UPPER-LOWER);
%M10 : (MA(P,10)-LOWER)/(UPPER-LOWER);

%B := (P-LOWER)/(UPPER-LOWER);
%B_UP :  IF(%B > 0.5,%B,DRAWNULL), CROSSDOT,COLORRED;
%B_DN :  IF(%B <= 0.5,%B,DRAWNULL), CROSSDOT,COLORGREEN;

{ BWIDTH:= (UPPER-LOWER)/MID; }

副图：布林带宽

布林带宽可以看作是对布林带通道宽度的量化。布林带宽度变窄时通常意味着变盘即将发生。但变盘的方向则需要由其它数据判断。

{N=20}

P1:= (H+L+C)/3;
P2:= (H+L+O+C)/4;
P3 := C;
P  := P1;
MID:=MA(P,N);
VART3:=STD(P,N);
UPPER:=MID+2*VART3;
LOWER:=MID-2*VART3;
%B := (P-LOWER)/(UPPER-LOWER);
BWIDTH: (UPPER-LOWER)/MID*100;